海外FXのスプレッドは狭いほど得なのか
実質コストの計算式とEAが実運用で負ける本当の理由

//+------------------------------------------------------------------+
//| 本コードは本人利用に限り自由に使用可。                             |
//| 再配布・商用利用・販売は禁止。                                     |
//| スプレッドをティックごとに記録し、CSVへ出力する                     |
//+------------------------------------------------------------------+
#property strict

input int    InpFlushSec = 60;      // 何秒ごとにファイルへ書き出すか
input string InpFileName = "spread_log.csv";

int    g_handle = INVALID_HANDLE;
datetime g_lastFlush = 0;

int OnInit()
{
   // 共通フォルダではなく MQL5/Files に出力
   g_handle = FileOpen(InpFileName, FILE_WRITE|FILE_READ|FILE_CSV|FILE_ANSI, ',');
   if(g_handle == INVALID_HANDLE)
   {
      Print("ファイルを開けません: ", GetLastError());
      return(INIT_FAILED);
   }
   FileSeek(g_handle, 0, SEEK_END);
   // ヘッダは空ファイルのときだけ書く
   if(FileTell(g_handle) == 0)
      FileWrite(g_handle, "datetime", "symbol", "bid", "ask", "spread_points", "spread_pips");
   return(INIT_SUCCEEDED);
}

void OnDeinit(const int reason)
{
   if(g_handle != INVALID_HANDLE) FileClose(g_handle);
}

void OnTick()
{
   MqlTick t;
   if(!SymbolInfoTick(_Symbol, t)) return;

   double point  = SymbolInfoDouble(_Symbol, SYMBOL_POINT);
   int    digits = (int)SymbolInfoInteger(_Symbol, SYMBOL_DIGITS);
   if(point <= 0.0) return;

   // 3桁/5桁業者は 10point = 1pip
   double pipSize = (digits == 3 || digits == 5) ? point * 10.0 : point;

   double spreadPoints = (t.ask - t.bid) / point;
   double spreadPips   = (t.ask - t.bid) / pipSize;

   FileWrite(g_handle,
             TimeToString(t.time, TIME_DATE|TIME_SECONDS),
             _Symbol,
             DoubleToString(t.bid, digits),
             DoubleToString(t.ask, digits),
             DoubleToString(spreadPoints, 1),
             DoubleToString(spreadPips, 2));

   if(TimeCurrent() - g_lastFlush >= InpFlushSec)
   {
      FileFlush(g_handle);
      g_lastFlush = TimeCurrent();
   }
}

# 本コードは本人利用に限り自由に使用可。再配布・商用利用・販売は禁止。
# MT5が出力した spread_log.csv を時間帯別に集計する
import pandas as pd

df = pd.read_csv("spread_log.csv")
df["datetime"] = pd.to_datetime(df["datetime"])
df = df.set_index("datetime")

# MT5サーバー時間 -> 日本時間に補正（サーバーのGMTオフセットに合わせて調整）
SERVER_TO_JST_HOURS = 6
df.index = df.index + pd.Timedelta(hours=SERVER_TO_JST_HOURS)

df["hour"] = df.index.hour

summary = df.groupby("hour")["spread_pips"].agg(
    count="count",
    mean="mean",
    median="median",
    p75=lambda s: s.quantile(0.75),
    p95=lambda s: s.quantile(0.95),
    max="max",
).round(2)

print("=== 時間帯別スプレッド（日本時間・pips） ===")
print(summary.to_string())

print("\n=== 全体 ===")
print(f"平均          : {df['spread_pips'].mean():.2f} pips")
print(f"中央値        : {df['spread_pips'].median():.2f} pips")
print(f"75パーセンタイル: {df['spread_pips'].quantile(0.75):.2f} pips  <- バックテストにはこの値を使う")
print(f"95パーセンタイル: {df['spread_pips'].quantile(0.95):.2f} pips")

# 稼働させたい時間帯だけを抜き出して実効スプレッドを見る
TRADING_HOURS = range(21, 26)   # 日本時間21時〜翌1時（25=翌1時）
mask = df["hour"].isin([h % 24 for h in TRADING_HOURS])
print(f"\n稼働時間帯の平均: {df.loc[mask, 'spread_pips'].mean():.2f} pips")